【Windows】Windows11の右クリックをWindows10仕様に戻す
karrinn
ソフトウェアエンジニア目次
警告
- 本記事の通りに作業するとWindowsのレジストリエディタに変更を加えます。自己責任でお願いします。
背景
数年前にWindows11が出て便利になったこともあれば面倒に感じることもあります。筆者にとって一番手間に感じているのがエクスプローラでの右クリックの動作が変わったことです。
様々なソフトウェアをインストールしてPCを使っている方は、右クリックのコンテキストメニューに追加して使われている方もいるかと思います（7zipとか）
筆者は職業柄使用するＰＣが１年間に５、６回変わり、最初のころはググって出てきた手順を参考に設定していましたが、レジストリをGUIでたどるのはむしろヒューマンエラーが起きそうで、なんといっても面倒でした。なのである時からはバッチファイルを作成してそれを使っています。
読んでくださっている方にも共有しますので、お役立ていただければ幸いです。
ただし、冒頭にも記載した通りレジストリというWindowsＰＣにとってすごく大事なところに変更を加えますので、自己責任で行ってください。
作業
- メモ帳や、エディタに以下のコードを貼り付け、「ClassicContextMenuToggle.bat」という名前で保存します。
- 保存した「ClassicContextMenuToggle.bat」をダブルクリックして実行します。
ClassicContextMenuToggle.bat
@echo off
echo Windows 11の右クリックメニューをWindows 10仕様に変更するツール
echo.
:: 管理者権限チェック
fsutil dirty query %systemdrive% >nul 2>&1
if %errorlevel% neq 0 (
echo 管理者権限で実行する必要があります。
echo 管理者として再実行します...
echo.
:: 管理者として再実行するスクリプト
powershell -Command "Start-Process '%~dpnx0' -Verb RunAs"
exit /b
)
:: ここから管理者権限で実行されるコード
setlocal
set "KEY_NAME=HKEY_CURRENT_USER\Software\Classes\CLSID"
set "CLSID={86ca1aa0-34aa-4e8b-a509-50c905bae2a2}"
set "target=%KEY_NAME%\%CLSID%\InprocServer32"
:: キーの存在確認
reg query "%KEY_NAME%\%CLSID%" >nul 2>&1
if %errorlevel% neq 0 (
echo CLSIDキーが存在しません。新しく作成します...
reg add "%KEY_NAME%\%CLSID%" /f >nul 2>&1
)
:: InprocServer32キーの存在確認
reg query "%target%" /ve >nul 2>&1
if %errorlevel% equ 0 (
:: キーが存在する場合は削除してWindows 11スタイルに戻す
reg delete "%KEY_NAME%\%CLSID%" /f >nul 2>&1
echo ***********************************************************************
echo 右クリックを押したときの動作をWindows 11仕様にしました。
echo 変更を有効にするにはエクスプローラーの再起動またはPCの再起動が必要です。
echo ***********************************************************************
) else (
:: キーが存在しない場合は作成してWindows 10スタイルにする
reg add "%target%" /f >nul 2>&1
reg add "%target%" /ve /t REG_SZ /d "" /f >nul 2>&1
echo ***********************************************************************
echo 右クリックを押したときの動作をWindows 10以前の仕様に戻しました。
echo 変更を有効にするにはエクスプローラーの再起動またはPCの再起動が必要です。
echo ***********************************************************************
)
pause
:: エクスプローラーを再起動するオプション
set /p "restart_explorer=エクスプローラーを今すぐ再起動しますか？ (y/n) "
if /i "%restart_explorer%"=="y" (
echo エクスプローラーを再起動しています...
taskkill /f /im explorer.exe >nul 2>&1
start explorer.exe
echo 完了しました。
pause
exit /b
)
:: PCを再起動するオプション
set /p "restart=PCを再起動しますか？ (y/n) "
if /i "%restart%"=="y" (
shutdown /r /t 0
) else (
echo 設定を有効にするには、エクスプローラーまたはPCを再起動してください。
pause
)まとめ
これでWindows10の頃のコンテキストメニューがいきなり起動するようになります。
誰かのお役に立てれば幸いです。
まだコメントはありません。最初のコメントを残しませんか？